// License: CC0
//
// To the extent possible under law, Clementine Computing LLC has waived
// all copyright and related or neighboring rights to this file.
//
// This work is published from: United States.
//

include <PopufareHousingCommon.scad>

module PopufareHousingSideLeftPlate() {
  w = POPUFARE_HOUSING_DEPTH;
  h = POPUFARE_HOUSING_HEIGHT;
  
  br = POPUFARE_BRACKET_D/2.0;
  bx = POPUFARE_BRACKET_CX;
  de = POPUFARE_BRACKET_DE;
  des = POPUFARE_BRACKET_DE_SHORT;
  
  dh = POPUFARE_HOUSING_HEIGHT - POPUFARE_FRONT_HEIGHT;
  alen = dh*sqrt(2.0);
  w_right = w - dh;
  
  lip = _MATERIAL_THICKNESS;
  
  buck_dw0 = POPUFARE_BUCK_HOLE_WIDTH0;
  buck_dw1 = POPUFARE_BUCK_HOLE_WIDTH1;
  buck_dh = POPUFARE_BUCK_HOLE_DH;
  buck_r = POPUFARE_BUCK_HOLE_R;
  
  buck_center = [35,-3];

  difference() {
    union() {
      square([w,h], center=true);
      
      // bottom skirt to cover under plate
      //
      translate([0,-(h/2 + lip/2)]) square([w,lip], center=true);
      
      translate([-(w/2-dh),h/2 + lip/2])
      difference() {
        square([lip, lip], center=true);
        translate([-lip,-lip])  rotate(45, [0,0,1]) square([3*lip, 3*lip]);
      }
      
      translate([-w/2,h/2 - dh])
      difference() {
        square([lip, lip], center=true);
        translate([-lip,-lip])  rotate(45, [0,0,1]) square([3*lip, 3*lip]);
      }
    }
    
    // chop off angle
    //
    translate([-w/2,-(h/2-POPUFARE_FRONT_HEIGHT)]) rotate(45, [0,0,1]) square([4*w,4*w]);
    
    // bottom bracket
    //
    translate([-(w/2-de), -(h/2-bx) ]) circle(br);
    translate([ (w/2-de), -(h/2-bx) ]) circle(br);
    
    // front bracket
    //
    translate( [ -(w/2-bx), -(h/2 - POPUFARE_FRONT_HEIGHT/2) ]) circle(br);
    
    // front angle bracket
    //
    translate([-w/2, -(h/2-POPUFARE_FRONT_HEIGHT)]) rotate(45, [0,0,1])
      translate([de/2, -bx]) circle(br);
    translate([-w/2, -(h/2-POPUFARE_FRONT_HEIGHT)]) rotate(45, [0,0,1])
      translate([alen - de/2, -bx]) circle(br);
      
    // top bracket
    //
    //translate([ (w/2 - (w_right/2.0)), (h/2 - bx) ]) circle(br);
    translate([ (w/2 - des), (h/2 - bx) ]) circle(br);
    translate([ (w/2 - (w_right) + des), (h/2 - bx) ]) circle(br);
    
    // buck screw attachment
    //
    translate(buck_center)
    union() {
      translate([-buck_dw0/2, -buck_dh/2]) circle(buck_r);
      translate([ buck_dw0/2, -buck_dh/2]) circle(buck_r);
      translate([-buck_dw1/2,  buck_dh/2]) circle(buck_r);
      translate([ buck_dw1/2,  buck_dh/2]) circle(buck_r);
    }
  }
}

//PopufareHousingSideLeftPlate();