// License: CC0
//
// To the extent possible under law, Clementine Computing LLC has waived
// all copyright and related or neighboring rights to this file.
//
// This work is published from: United States.
//

include <PopufareHousingCommon.scad>

module PopufareHousingSideRightPlate() {
  w = POPUFARE_HOUSING_DEPTH;
  h = POPUFARE_HOUSING_HEIGHT;
  
  br = POPUFARE_BRACKET_D/2.0;
  bx = POPUFARE_BRACKET_CX;
  de = POPUFARE_BRACKET_DE;

  des = POPUFARE_BRACKET_DE_SHORT;
  
  dh = POPUFARE_HOUSING_HEIGHT - POPUFARE_FRONT_HEIGHT;
  alen = dh*sqrt(2.0);
  w_right = w - dh;

  difference() {
    square([w,h], center=true);
    
    // chop off angle
    //
    translate([ w/2,-(h/2-POPUFARE_FRONT_HEIGHT)]) rotate(-45, [0,0,1])
      translate([-4*w,0]) square([4*w,4*w]);
    
    // bottom bracket
    //
    translate([-(w/2-de), -(h/2-bx) ]) circle(br);
    translate([ (w/2-de), -(h/2-bx) ]) circle(br);
    
    // front bracket
    //
    translate( [ (w/2-bx), -(h/2 - POPUFARE_FRONT_HEIGHT/2) ]) circle(br);
    
    // front angle bracket
    //
    translate([ w/2, -(h/2-POPUFARE_FRONT_HEIGHT)]) rotate(-45, [0,0,1])
      translate([-de/2, -bx]) circle(br);
    translate([ w/2, -(h/2-POPUFARE_FRONT_HEIGHT)]) rotate(-45, [0,0,1])
      translate([-(alen - de/2), -bx]) circle(br);
      
    // top bracket
    //
    translate([ -(w/2  - des), (h/2 - bx) ]) circle(br);
    translate([ -w/2 + w_right - des, (h/2 - bx) ]) circle(br);
    
    // no back bracket
    //
  }
}

//PopufareHousingSideRightPlate();
