popufare/experiment/production/adapter-box/PopufarePowerAdapterTop.scad

// License: CC0
//
// To the extent possible under law, Clementine Computing LLC has waived
// all copyright and related or neighboring rights to this file.
//
// This work is published from: United States.
//

include <PopufareHousingCommon.scad>

module PopufarePowerAdapterTopPlate() {
  _w = _POWER_BOX_WIDTH;
  _h = _POWER_BOX_HEIGHT;
  _r = _POWER_BOX_R;

  conw = _POWER_CONNECTOR_WIDTH;
  conh = _POWER_CONNECTOR_HEIGHT;

  piu_usb_h = _POWER_BOX_PIU_USB_H;

  buck_dw = _PIU_BUCK_DW;
  buck_r = _PIU_BUCK_R;
  buck_cx = _w/2 + 2*buck_r;
  buck_cy = -_h/12;

  difference() {
    union() {
      rounded_rect(_w, _h, _r);

      translate([buck_cx-3*buck_r,buck_cy]) square([6*buck_r, buck_dw+5*buck_r], center=true);
      translate([buck_cx,buck_cy])
         rounded_rect(5*buck_r, buck_dw + 5*buck_r, 2*buck_r);
         //rounded_rect(buck_dw + 5*buck_r, 5*buck_r, 2*buck_r);
    }

    // power connector access
    //
    translate([0, _h/2 - conh/2 -  6*_r]) square([conw, conh], center=true);

    // buck converter screw holes
    //
    translate([buck_cx, buck_cy - buck_dw/2 ]) circle(buck_r);
    translate([buck_cx, buck_cy + buck_dw/2 ]) circle(buck_r);

    // housing holes
    //
    translate([ (_w/2 - 3*_r), (_h/2 - 3*_r)]) circle(_r);
    translate([-(_w/2 - 3*_r), (_h/2 - 3*_r)]) circle(_r);
    translate([-(_w/2 - 3*_r),-(_h/2 - 3*_r)]) circle(_r);
    translate([ (_w/2 - 3*_r),-(_h/2 - 3*_r)]) circle(_r);

    // max232 converter. It has no holes so we'll be using cable ties
    //
    translate([5,5])
    union() {
      translate([-_POWER_BOX_STRAP_DW/2, -_POWER_BOX_STRAP_DH/2]) circle(_r);
      translate([ _POWER_BOX_STRAP_DW/2, -_POWER_BOX_STRAP_DH/2]) circle(_r);
      translate([ _POWER_BOX_STRAP_DW/2,  _POWER_BOX_STRAP_DH/2]) circle(_r);
      translate([-_POWER_BOX_STRAP_DW/2,  _POWER_BOX_STRAP_DH/2]) circle(_r);
    }

    // PIU rs232 ttl USB out
    //
    translate([-_w/2+_PIU_USB_HOLE_DE, piu_usb_h + _PIU_USB_HOLE_DW/2])
      circle(_PIU_USB_HOLE_R);
    translate([-_w/2+_PIU_USB_HOLE_DE, piu_usb_h - _PIU_USB_HOLE_DW/2])
      circle(_PIU_USB_HOLE_R);

    // various holes for connections
    //
    translate([-_w/2+_PIU_USB_HOLE_DE*2, piu_usb_h + _PIU_USB_HOLE_DW/2+2*_r])
      circle(_r);
    translate([-_w/2+_PIU_USB_HOLE_DE*2, piu_usb_h - _PIU_USB_HOLE_DW/2-2*_r])
      circle(_r);

    translate([0,-_h/4+10]) circle(_r);
    translate([10,-_h/4 + 10]) circle(_r);
    translate([0,-_h/4]) circle(_r);
    translate([0,-_h/4 - 10]) circle(_r);
    translate([10,-_h/4]) circle(_r);
    translate([10,-_h/4 - 10]) circle(_r);
  }
}

//PopufarePowerAdapterTopPlate();