popufare/experiment/production/housing/v-alfalfa-sprout/PopufareHousingSideLeft.scad

// License: CC0
//
// To the extent possible under law, Clementine Computing LLC has waived
// all copyright and related or neighboring rights to this file.
//
// This work is published from: United States.
//

include <PopufareHousingCommon.scad>

module PopufareHousingSideLeftPlate() {
  _mt = _MATERIAL_THICKNESS;

  w = POPUFARE_HOUSING_DEPTH;
  h = POPUFARE_HOUSING_HEIGHT;

  br = POPUFARE_BRACKET_D/2.0;
  bx = POPUFARE_BRACKET_CX;
  de = POPUFARE_BRACKET_DE;
  des = POPUFARE_BRACKET_DE_SHORT;

  dh = POPUFARE_HOUSING_HEIGHT - POPUFARE_FRONT_HEIGHT;
  alen = dh*sqrt(2.0);
  w_right = w - dh;

  defa = POPUFARE_BRACKET_DE_MEDIUM;

  lip = _MATERIAL_THICKNESS;

  spkr_dw = POPUFARE_SPEAKER_HOLE_WIDTH;
  spkr_dh = POPUFARE_SPEAKER_HOLE_HEIGHT;

  buck_dw0 = POPUFARE_BUCK_HOLE_WIDTH0;
  buck_dw1 = POPUFARE_BUCK_HOLE_WIDTH1;
  buck_dh = POPUFARE_BUCK_HOLE_DH;
  buck_r = POPUFARE_BUCK_HOLE_R;

  buck_center = [18,5];

  back_h = POPUFARE_HOUSING_HEIGHT - POPUFARE_HOUSING_BACK_LIP_HEIGHT;
  back_lip_inset = POPUFARE_HOUSING_BACK_LIP_INSET;
  back_lip_screw_h = (h/2 - dh + bx);

  overhang_w = POPUFARE_HOUSING_BACK_LIP_SPACE;
  overhang_h = POPUFARE_HOUSING_BACK_LIP_HEIGHT;

  difference() {
    union() {
      square([w,h], center=true);

      translate([-(w/2-dh),h/2 + lip/2])
      difference() {
        square([lip, lip], center=true);
        translate([-lip,-lip])  rotate(45, [0,0,1]) square([3*lip, 3*lip]);
      }

      translate([-w/2,h/2 - dh])
      difference() {
        square([lip, lip], center=true);
        translate([-lip,-lip])  rotate(45, [0,0,1]) square([3*lip, 3*lip]);
      }

      // back lip
      //
      translate([w/2 + overhang_w/2, -h/2 + overhang_h/2]) square([overhang_w, overhang_h], center=true);

    }

    // chop off angle
    //
    translate([-w/2,-(h/2-POPUFARE_FRONT_HEIGHT)]) rotate(45, [0,0,1]) square([4*w,4*w]);

    // bottom bracket
    //
    translate([-(w/2-de), -(h/2-bx) ]) circle(br);
    translate([ (w/2-de), -(h/2-bx) ]) circle(br);

    // front bracket
    //
    translate( [ -(w/2-bx), -(h/2 - POPUFARE_FRONT_HEIGHT/2) ]) circle(br);

    // front angle bracket
    //
    translate([-w/2, -(h/2-POPUFARE_FRONT_HEIGHT)]) rotate(45, [0,0,1])
      //translate([de/2, -bx]) circle(br);
      translate([defa, -bx]) circle(br);
    translate([-w/2, -(h/2-POPUFARE_FRONT_HEIGHT)]) rotate(45, [0,0,1])
      //translate([alen - de/2, -bx]) circle(br);
      translate([alen - defa, -bx]) circle(br);

    // top bracket
    //
    //translate([ (w/2 - (w_right/2.0)), (h/2 - bx) ]) circle(br);
    translate([ (w/2 - des), (h/2 - bx) ]) circle(br);
    translate([ (w/2 - (w_right) + des), (h/2 - bx) ]) circle(br);

    // buck screw attachment
    //
    translate(buck_center)
    union() {
      translate([-buck_dw0/2, -buck_dh/2]) circle(buck_r);
      translate([ buck_dw0/2, -buck_dh/2]) circle(buck_r);
      translate([-buck_dw1/2,  buck_dh/2]) circle(buck_r);
      translate([ buck_dw1/2,  buck_dh/2]) circle(buck_r);
    }

    // back panel brackets
    //
    translate([w/2 - bx, h/2 - back_h/2]) circle(br);

    // lip attachment bracket
    //
    translate([ (w/2 - back_lip_inset/2), h/2 - back_h + bx]) circle(br);
    translate([ (w/2 - back_lip_inset/2), h/2 - back_h - bx - _mt]) circle(br);


    // speaker access and mounting screw holes
    //
    spkr_cx = 0;
    spkr_cy = -45;
    spkr_r = 2*spkr_dw/5;
    offset_x = 4.5;
    _w = 2.5;
    translate([spkr_cx,spkr_cy]) rotate(45, [0,0,1]) rounded_rect(_w,2*spkr_r, _w/2);
    translate([spkr_cx,spkr_cy]) rotate(45, [0,0,1]) translate([offset_x,0]) rounded_rect(_w,2*sqrt(spkr_r*spkr_r - offset_x*offset_x), _w/2);
    translate([spkr_cx,spkr_cy]) rotate(45, [0,0,1]) translate([2*offset_x,0]) rounded_rect(_w,2*sqrt(spkr_r*spkr_r - (2*2*offset_x*offset_x)), _w/2);
    translate([spkr_cx,spkr_cy]) rotate(45, [0,0,1]) translate([3*offset_x,0]) rounded_rect(_w,2*sqrt(spkr_r*spkr_r - (3*3*offset_x*offset_x)), _w/2);

    translate([spkr_cx,spkr_cy]) rotate(45, [0,0,1]) translate([-offset_x,0]) rounded_rect(_w,2*sqrt(spkr_r*spkr_r - offset_x*offset_x), _w/2);
    translate([spkr_cx,spkr_cy]) rotate(45, [0,0,1]) translate([-2*offset_x,0]) rounded_rect(_w,2*sqrt(spkr_r*spkr_r - (2*2*offset_x*offset_x)), _w/2);
    translate([spkr_cx,spkr_cy]) rotate(45, [0,0,1]) translate([-3*offset_x,0]) rounded_rect(_w,2*sqrt(spkr_r*spkr_r - (3*3*offset_x*offset_x)), _w/2);

    translate([spkr_cx - spkr_dw/2,spkr_cy - spkr_dh/2]) circle(POPUFARE_SPEAKER_HOLE_R);
    translate([spkr_cx + spkr_dw/2,spkr_cy - spkr_dh/2]) circle(POPUFARE_SPEAKER_HOLE_R);

    translate([spkr_cx - spkr_dw/2,spkr_cy + spkr_dh/2]) circle(POPUFARE_SPEAKER_HOLE_R);
    translate([spkr_cx + spkr_dw/2,spkr_cy + spkr_dh/2]) circle(POPUFARE_SPEAKER_HOLE_R);

  }
}

//PopufareHousingSideLeftPlate();